#!/bin/csh -f
umask 002

set rev0 = 352
set rev1 = `svn info | awk '/^Revision:/{print $NF}'`
set ud = ~aftp/spm/spm5_updates
cat<<WOOF >! $ud/Updates_README.txt
  ___  ____  __  __
 / __)(  _ \(  \/  )
 \__ \ )___/ )    (   Statistical Parametric Mapping
 (___/(__)  (_/\/\_)  SPM5 : Updates to Revision $rev1
______________________________________________________________
Download Updates_$rev1.tar.gz and unpack it into your spm5
directory, overwriting any existing files. Note that the
distributed version of spm5.tar.gz is Revision $rev0.

WOOF
date >> $ud/Updates_README.txt
cat<<WOOF >> $ud/Updates_README.txt
______________________________________________________________

WOOF

cd /local/spm/spm5
svn log  -r{$rev0}:{$rev1} -v --xml >! $ud/Updates_Log.xml
svn diff -r{$rev0}:{$rev1} >! $ud/Updates_Diff.txt
svn log  -r{$rev0}:{$rev1} -v >! /tmp/log$$.txt
cat /tmp/log$$.txt >> $ud/Updates_README.txt

set files = (`grep '   .*/trunk/' < /tmp/log$$.txt | awk '{print $2}' | sed 's/^\/trunk\///'`)

foreach f ($files)
    if (x$f:e == 'xdll') then
        set mod = 0775
    else
        set mod = 0664
    endif
    set f1 = $ud/$f
    set op0 = -f
    if (-d $f) then
        set op0 = '-d'
        set mod = 0775
    else
        if (-f $f) then
            set f1  = $f1:h
            echo $f >>! /tmp/include0$$.txt
            set op0 = -f
            \rm -f $ud/$f
        else
            echo $f >>! $ud/now_gone.txt
        endif
    endif
    # /usr/sbin/install $op0 $f1 -m $mod `pwd`/$f
end
sort -u < /tmp/include0$$.txt > /tmp/include$$.txt

\rm $ud/Updates_*.tar.gz
tar cvf - -I /tmp/include$$.txt | gzip -v >! $ud/Updates_$rev1.tar.gz
\rm /tmp/log$$.txt /tmp/include$$.txt /tmp/include0$$.txt

# No space, so just do the tar.gz file
#cd $ud
#gunzip < Updates_$rev1.tar.gz | tar xvf -